setthd.f

Go to the documentation of this file.

      SUBROUTINE setthd(X,Y)  
C  VERSION OF 1/27/85
C  PURPOSE
C    COMPUTES ROTATION MATRIX FOR CONVERSION FROM ORBITAL  
C    ELEMENTS TO CARTESIAN COORDINATES 
C  INPUT 
C    X      = 7-D ORBITAL ELEMENT SET OF THIRD BODY  
C     (1)   = SEMI-MAJOR AXIS (KM)
C     (2)   = ECCENTRICITY
C     (3)   = INCLINATION (RAD)
C     (4)   = LONGGITUDE OF ASCENDING NODE (RAD)
C     (5)   = ARGUMENT OF PERIAPSIS (RAD)
C     (6)   = MEAN ANOMALY OF THE THIRD BODY AT TR (RAD)
C     (7)   = MEAN MOTION (RAD/SEC)
C    Y      = 7-D ELEMENTS TO TRANFORM ORBITAL ELEMENTS TO CART.
C             COORD
C      (1)  = L1, COS(NODE)*COS(W) - SIN(NODE)*SIN(W)*COS(I)  
C      (2)  = M1, SIN(NODE)*COS(W) + COS(NODE)*SIN(W)*COS(I)  
C      (3)  = N1, SIN(W)*SIN(I)   
C      (4)  = L2, -COS(NODE)*SIN(W) - SIN(NODE)*COS(W)*COS(I) 
C      (5)  = M2, -SIN(NODE)*SIN(W) + COS(NODE)*COS(W)*COS(I) 
C      (6)  = N2, COS(W)*SIN(I)   
C      (7)  = SEMI-MINOR AXIS, A*SQRT(1-E*E)  
C  REFENENCES
C    JPL EM 312/87-153, 20 APRIL 1987
C    ORBITAL MOTION, A. E. ROY, 1978, P.102
C  ANALYSIS
C    J. H. KWOK - JPL  
C  PROGRAMMER
C    J. H. KWOK - JPL  
C  PROGRAM MODIFICATION  
C    NONE  
C  COMMENTS  
C    NONE  
C
      IMPLICIT DOUBLE PRECISION (a-h,o-z)   
      dimension x(7),y(7)   
      ci=dcos(x(3)) 
      si=dsin(x(3)) 
      cc=dcos(x(4)) 
      sc=dsin(x(4)) 
      cw=dcos(x(5)) 
      sw=dsin(x(5)) 
      y(1)=cc*cw-sc*sw*ci   
      y(2)=sc*cw+cc*sw*ci   
      y(3)=sw*si
      y(4)=-cc*sw-sc*cw*ci  
      y(5)=-sc*sw+cc*cw*ci  
      y(6)=cw*si
      y(7)=dsqrt(1.d0-x(2)**2)*x(1) 
      RETURN
      END