legend.f

Go to the documentation of this file.

      SUBROUTINE legend(N,M,X,P)
C  VERSION OF 2/9/87
C  PURPOSE   
C    COMPUTES LEGENDRE AND ASSOCIATED LEGENDRE FUNCTIONS UP TO 
C    DEGREE N AND ORDER M, N.GE.M  
C  INPUT 
C    N      = DEGREE OF SPHERICAL HARMONICS
C    M      = ORDER OF SPHERICAL HARMONICS 
C    X      = SIN (LATITUDE)   
C  OUTPUT
C    P      = 2-D LEGENDRE FUNCTIONS   
C  CALLED BY SUBROUTINES 
C    DER   
C  CALL SUBROUTINES  
C    NONE  
C  REFERENCES
C    JPL EM 312/87-153, 20 APRIL 1987
C  ANALYSIS
C    J. H. KWOK - JPL  
C  PROGRAMMER
C    J. H. KWOK - JPL  
C  PROGRAM MODIFICATION  
C    NONE  
C  COMMENTS  
C    THIS PROGRAM HAS BEEN DIMENSION FOR MAXIMUM OF 40X40 HARMONICS.   
C    FOR HIGHER ORDER OR DEGREE, REDIMENSION P( , ). THE FUNCTIONS 
C    ARE STORED AS PIJ=P(I+1,J+1).  INPUT N CAN BE .GE. M. 
C   
      IMPLICIT DOUBLE PRECISION (a-h,o-z)   
      dimension p(41,41)
      DATA one/1.d0/
      p(1,1)=one
      p(2,1)=x
C *** COMPUTE LEGENDRE FUNCTIONS UP TO DEGREE N 
      DO 100 i=2,n  
  100 p(i+1,1)=((2*i-1)*x*p(i,1)-(i-1)*p(i-1,1))/i  
      IF (m.EQ.0) RETURN
C *** COMPUTE ASSOCIATED LEGENDRE FUNCTIONS UP TO ORDER M   
      y=dsqrt(one-x*x) 
      p(2,2)=y  
      IF (m.EQ.1) GO TO 400 
C *** THIS IS THE SECTORIAL PART OF THE ASSOCIATED FUNCTIONS
      DO 200 i=2,m  
  200 p(i+1,i+1)=(2*i-1)*y*p(i,i)   
  400 CONTINUE  
C *** THIS THE TESSERAL PART OF THE ASSOCIATED FUNCTIONS
      DO 500 i=2,n  
      i1=i-1
      DO 300 j=1,i1 
      IF (j.GT.m) GO TO 500 
      p(i+1,j+1)=(2*i-1)*y*p(i,j)   
      IF (i-2.GE.j) p(i+1,j+1)=p(i+1,j+1)+p(i-1,j+1)
  300 CONTINUE  
  500 CONTINUE  
      RETURN
      END