kozsak2.f

Go to the documentation of this file.

      SUBROUTINE kozsak2(IFLAG,GE,RE,AJ2,X,XN,XI,IER)
 
C $Header: /app/shared/RCS/irix-5.2/seawifsd/src/mops/mopsV4.1/swfnav/kozsak2.f,v 1.1 1995/01/17 23:02:23 seawifsd Exp seawifsd $
C $Log: kozsak2.f,v $
C Revision 1.1  1995/01/17 23:02:23  seawifsd
C Initial revision
C                                                                        
C  VERSION 4/28/88
C  PURPOSE
C    CONVERTS BETWEEN MEAN AND OSCULATING ORBITAL ELEMENTS
C  INPUT
C    IFLAG   = 1, MEAN TO OSCULATING
C            = 2, OSCULATING TO MEAN
C            = 3, OSCULATING TO MEAN WITH INITIAL GUESS FOR MEAN
C    GE      = PRODUCT OF GRAVITATIONAL CONSTANT * MASS OF
C              PLANET (KM**3/SEC**2)
C    RE      = RADIUS OF PLANET (KM)
C    AJ2     = J2 = -C20
C    X       = AN ARRAY OF 6 ORBITAL ELEMENTS, A, E, I, NODE, W, AND M
C              (KM, RAD)
C    XI      = AN ARRAY OF 6 INITIAL MEAN ELEMENTS
C  OUTPUT ARGUMENTS
C    XN      = AN ARRAY OF 6 ORBITAL ELEMENTS AFTER CONVERSION
C    IER     = ERROR FLAG (SET TO 1 IF OSCULATING-TO-MEAN CONVERSION
C               DOES NOT CONVERGE)
C  CALL SUBROUTINES
C    DELM
C  REFERENCES
C    JPL IOM 312/85.2-927, 23 JANUARY 1985, BY C. UPHOFF
C    JPL EM 312/87-153, 20 APRIL 1987
C  ANALYSIS
C    JOHNNY H. KWOK - JPL
C  PROGRAMMER
C    JOHNNY H. KWOK - JPL
C  MODIFICATIONS
C    ADDED OPTION TO INPUT INITIAL GUESS AT MEAN ELEMENTS FOR 
C    OSCULATING-TO-MEAN CONVERSION AND CONVERGENCE TEST FOR CONVERSION
C    F.S. PATT, GSC, 29 NOVEMBER 1993
C
C    CHANGED MAXIMUM NUMBER OF ITERATIONS TO 200 AND INITIALIZED ERROR
C    RETURN CODE.  F.S. PATT, GSC, OCTOBER 26, 1993
C
C  COMMENTS
C    THIS PROGRAM USES AN ALGORITHM DERIVED BY C. UPHOFF (REF) WHICH
C    USES A COMBINATION OF KOZAI'S AND IZSAK'S THEORY.
C
      IMPLICIT DOUBLE PRECISION (a-h,o-z)
      dimension x(6),xn(6),xi(6),dx(6),xtol(6)
      LOGICAL DONE
      DATA tpi/6.283185307179586d0/
      DATA zero/0.d0/,rtol/1.d-6/
      DATA xtol/1.d-5,1.d-8,2*1.d-7,2*1.d-5/
      pi = tpi/2.d0
      p3o2 = 3.d0*tpi/2.d0
C      IMAX=5
C      IF (X(2).LT.1.D-1) IMAX=10
C      IF (X(2).LT.1.D-2) IMAX=20
C      IF (X(2).LT.1.D-3) IMAX=30
      imax = 200
      ier = 0
      IF (iflag.NE.3) THEN
        DO i=1,6
          xi(i)=x(i)
        END DO
      END IF
      icount=0
c       print *,' '
c       print *,x
      IF (iflag.GT.1) THEN
        done = .false.
        dowhile((.NOT.done).AND.(icount.LT.imax))
          CALL delm(re,ge,aj2,xi,dx)
          DO i=3,6
            dx(i)=dmod(dx(i)+p3o2,tpi)-pi
          END DO
c         print *,dx
          icount = icount + 1
          fac = 0.5*(1.d0-abs(dx(5))/pi)
          done = .true.
          DO i=1,6
            xdel = (x(i)-dx(i)-xi(i))
            IF (i.GE.3) xdel = dmod(xdel+p3o2,tpi)-pi
            rdel = xdel/dx(i)
            IF ((abs(xdel).GT.xtol(i)).AND.(abs(rdel).GT.rtol)) 
     *        done = .false.
            xn(i)=xi(i) + xdel*fac
          END DO
          IF (xn(2).LT.zero) xn(2)=zero
c      DO 30 I=3,6
c   30 XN(I)=DMOD(XN(I)+TPI,TPI)
          DO i=1,6
            xi(i)=xn(i)
          END DO
        ENDDO
        print *,'KOZSAK2:  Mean elements converged in ',icount,
     *    ' iterations'
        IF (icount.EQ.imax) ier = 1
      ELSE
        CALL delm(re,ge,aj2,xi,dx)
        DO i=1,6
          xn(i)=xi(i)+dx(i)
        ENDDO
      ENDIF
  900 CONTINUE
      DO i=3,6
        xn(i)=dmod(xn(i)+tpi,tpi)
      END DO
      RETURN
      END