angles.f

Go to the documentation of this file.

      SUBROUTINE angles(M,A,B,CN,SN,TN) 
C  VERSION OF 4/2/87
C  PURPOSE   
C    COMPUTES COS(M*A), SIN(M*A), M*TAN(B) AND STORE VALUES IN 
C    ARRAYS CN, SN, TN 
C  INPUT 
C    M      = ORDER OF SPHERICAL HARMONICS TO BE EVALUATED 
C    A      = LONGITUDE FROM GREENWICH (RAD)
C    B      = LATITUDE (RAD)
C  OUTPUT
C    CN     = M-D ARRAY OF COS VALUES  
C    SN     = M-D ARRAY OF SIN VALUES  
C    TN     = M-D ARRAY OF TAN VALUES  
C  CALLED BY SUBROUTINES 
C    DER   
C  CALL SUBROUTINES  
C    NONE  
C  REFERENCES
C    JPL EM 312/87-153, 20 APRIL 1987
C  ANALYSIS  
C    J. H. KWOK - JPL  
C  PROGRAMMER
C    J. H. KWOK - JPL  
C  PROGRAM MODIFICATIONS 
C    NONE  
C  COMMENTS  
C   
      IMPLICIT DOUBLE PRECISION (a-h,o-z)   
      dimension cn(41),sn(41),tn(41)
      DATA zero,one,two/0.d0,1.d0,2.d0/
      cn(1)=one
      sn(1)=zero
      tn(1)=zero
      IF (m.EQ.0) RETURN
      cn(2)=dcos(a) 
      sn(2)=dsin(a) 
      tn(2)=dtan(b) 
      IF (m.EQ.1) RETURN
      DO 100 i=2,m  
      cn(i+1)=two*cn(2)*cn(i)-cn(i-1)   
      sn(i+1)=two*cn(2)*sn(i)-sn(i-1)   
  100 tn(i+1)=tn(2)+tn(i)   
      RETURN
      END