dangle.f

Go to the documentation of this file.

**                                                                              
** INVOCATION NAME:  DANGLE                                                     
**                                                                              
** PURPOSE:  FUNCTION TO COMPUTE THE ANGLE BETWEEN TWO UNIT VECTORS             
**                                                                              
** INVOCATION METHOD:  X = DANGLE(A, B, TOLER, ANG)                             
**                                                                              
** ARGUMENT LIST:                                                               
** NAME    TYPE  USE PURPOSE                                                    
** A(3)    R*8    I  FIRST UNIT VECTOR                                          
** B(3)    R*8    I  SECOND UNIT VECTOR                                         
** TOLER   R*8    I  MAXIMUM MAGNITUDE OF DOT-PRODUCT BEFORE CROSS-             
**                   PRODUCT IS USED TO COMPUTE ANGLE.  IF DOT-PRODUCT          
**                   IS GREATER THAN TOLER, THEN THE ANGLE IS ARCSIN            
**                   OF THE MAGNITUDE OF THE CROSS-PRODUCT, OTHERWISE,          
**                   THE ARCCOS OF THE DOT-PRODUCT IS USED.                     
**                   (RECOMMENDED VALUE IS 0.99D0)                              
** ANG     R*8    O  ANGLE BETWEEN UNIT VECTORS A AND B IN RADIANS              
** DANGLE  R*8    O  ANGLE BETWEEN UNIT VECTORS A AND B IN RADIANS              
**                                                                              
** FILE/RECORD REFERENCES: NONE                                                 
**                                                                              
** GLOBAL REFERENCES: NONE                                                      
**                                                                              
** EXTERNAL REFERENCES: NONE                                                    
**                                                                              
** INTERNAL VARIABLES:                                                          
** VAR       TYPE  PURPOSE                                                      
** ACROSB(3) R*8   CROSS-PRODUCT OF A AND B                                     
** ADOTB     R*8   DOT-PRODUCT OF A AND B                                       
** CROSMG    R*8   MAGNITUDE OF CROSS-PRODUCT                                   
**                                                                              
** NOTES:                                                                       
**                                                                              
** CHANGE HISTORY:                                                              
** AUTHOR             CHG-ID   MMM.YY    CHG-SUMMARY                            
** B.GROVEMAN                  JUL.88    PDL                                    
** M.WOOLSEY                   AUG.88    CERTIFIED PDL                          
** R.COON                      NOV.88    ORIGINAL CODE                          
** B.GROVEMAN                  NOV.88    CERTIFIED CODE                         
** M. WOOLSEY                  AUG.89    CORRECTED ARCSIN METHOD                
**                                        RETURNING ANSWERS > PI / 2            
**                                                                              
** BEGIN PDL                                                                    
**      COMPUTE DOT-PRODUCT OF A AND B                                          
**      IF (DOT-PRODUCT LESS THAN TOLER) THEN                                   
**         ANGLE = ARCCOS(DOT-PRODUCT)                                          
**      ELSE                                                                    
**         COMPUTE CROSS-PRODUCT OF A AND B                                     
**         COMPUTE THE MAGNITUDE OF THE CROSS-PRODUCT                           
**         ANGLE = ARCSIN(MAGNITUDE OF CROSS-PRODUCT)                           
**         IF (DOT-PRODUCT IS LESS THAN ZERO) ANGLE = PI - ANGLE                
**      END IF                                                                  
**                                                                              
**      RETURN                                                                  
** END PDL                                                                      
**                                                                              
** MAIN ENTRY POINT TO DANGLE                                                   
************************************************************************        
C                                                                               
      FUNCTION dangle (A, B, TOLER, ANG)                                        
C                                                                               
C-----DECLARE ARGUMENTS                                                         
      real*8 a(3), b(3), toler, ang, dangle                                     
C                                                                               
C-----DECLARE LOCAL VARIABLES                                                   
      real*8 acrosb(3), adotb, crosmg                                           
      real*8 pi /3.141592653589793d+00/                                         
C                                                                               
      adotb = a(1)*b(1) + a(2)*b(2) + a(3)*b(3)                                 
      IF (abs(adotb) .LE. abs(toler)) THEN                                      
C                          USE DOT-PRODUCT                                      
        ang = acos(adotb)                                                       
        dangle = ang                                                            
      ELSE                                                                      
C                          USE CROSS PRODUCT FOR GREATER ACCURACY               
        acrosb(1) = a(2)*b(3) - a(3)*b(2)                                       
        acrosb(2) = a(3)*b(1) - a(1)*b(3)                                       
        acrosb(3) = a(1)*b(2) - a(2)*b(1)                                       
        crosmg = sqrt(acrosb(1)**2 + acrosb(2)**2 + acrosb(3)**2)               
        ang = asin(crosmg)                                                      
        IF (adotb .LT. 0.0d0)  ang = pi - ang                                   
        dangle = ang                                                            
      END IF                                                                    
C                                                                               
      RETURN                                                                    
      END